作者：广东在线游戏网日期：
返回目录：游戏资讯
#show [stance:1]冲锋; [stance:3]拦截 /dismount [mounted] /startattack /cast [nocombat,stance:1] 冲锋zhidao; [nocombat,nostance:1] 战斗姿态; [combat,nostance:3] 狂暴姿版态; [combat,stance:3] 拦截 能用，我玩的就是战士，正在玩，我切权换到游戏直接复制过来的。战斗姿态时，冲锋无CD，则冲锋，冲锋有CD，则自动切换狂暴姿态拦截。狂暴姿态时如果战斗中，则拦截，除非拦截CD，如果不在战斗中，自动切换战斗姿态冲锋
来自NGA的支援。。。ZS宏基本全了~
这里列出tbc里最常见实用的一些战士宏。由于我用的是英文版，写一些技能和物品的中文名称可能会有差错，不过意思应该是明白的。
如果一个宏不工作:
1.先看看是否有中文名不正确，以及是否有全角标点符号。
2.再试着在游戏里打一遍而不要直接复制粘帖。
对战士来说，tbc的宏有两个最明显的变化：
1。判断语句失效。类似“如果.......那么.......否则......”的语句一概不能再用。
具体举例如目标20%以下放斩杀，否则放致死的宏不行了，又或者45怒以上点亮英勇，否则用致死，等等
2。包含一大堆 /施放 的宏不能再用。比如：
/cast 盾牌猛击
/cast 复仇
/cast 破甲
/cast 盾牌格挡
这个傻瓜宏如今行不通。在旧的wow里，这个宏如果盾猛不能用，那么程序将跳过它并检查复仇，如果不行就看破甲，以此类推，每按一次至少都会有一个命令被执行。但tbc里一旦某一步不能用，程序将卡在这里，后面所有的触发同种公共cd的技能都被华丽地无视了，仅有少数“点亮”型技能能够继续被执行，如英勇和顺劈。所以
/cast 压制
/stopcasting
/cast 致死打击
永远放不出致死。而
/cast 压制
/stopcasting
/cast 英勇打击
可以，因为英勇并不占用公共cd。此外
/cast 压制
/stopcasting
/cast 狂暴姿态
可以。因为姿态切换有着自己的独立1秒的公共cd。最后是
/cast 冲锋
/stopcasting
/cast 英勇
/stopcasting
/cast 狂暴姿态
是可行的。因为冲锋/切姿态是互相独立的cd，而英勇不属于任何一种，因此一键可以做这三件事。这是经典冲锋宏能够再现的基础。
其实有两种方法可以部分绕过这些限制，一是施放序列/castsequence，另一个是随机施放/castrandom，但效果很不好，不如不用，不提也罢
以上是关于战士的宏的简单的介绍，希望看了的人对哪些宏能用，哪些要被淘汰心里有底。也希望大家能够举一反三，很多时候不少小宏都是同一类型的变体而已。
0。开始攻击
/startattack
这简单的一行能让你开始攻击目标，并且怎么按都不会停止。比如你可以将其跟致死合用:
/startattack
/cast 致死打击
这样不管有没有怒放致死，按这个宏都会让你开始攻击。
如果你习惯于单独将其作为一个按钮，那么加上一行：
#show 攻击
/startattack
1。冲锋/拦截/断筋/切姿态
#show [stance:1]冲锋; [stance:3]拦截
/startattack
/cast 断筋
/stopcasting
/cast [nocombat,stance:1] 冲锋; [nocombat,nostance:1] 战斗姿态; [combat,nostance:3] 狂暴姿态; [combat,stance:3] 拦截
鉴于不少人反映切狂暴有时会误事，把上面加粗部分删除就能去掉这宏切狂暴姿态的能力
战斗外冲锋，如果不在战斗姿态则会切过去，然后再按一下
战斗中拦截，如果不在狂暴姿态则会切过去，然后再按一下
任何情况下近身后断筋
战斗姿态下显示冲锋的冷却，狂暴姿态下显示拦截的冷却
在马上则自动下马+冲锋，只需按一次
与旧的宏系统能做的事情相比，少了一个判断如果怒气不够10则先血怒再拦截的功能
虽然省事且可靠，但从技巧上讲，断筋最好还是在快捷栏上占独立的位置。如果想将冲锋拦截和别的技能绑定，把断筋改成那个技能名称就行
还有就是别在空中乱按这个....
这个宏在15楼有进一步细化，不过一般用不到。
2。投掷/开枪/射箭 （感谢65,104,126楼)
/cast [equipped:投掷武器] 投掷; 射击
/equip [equipped:弓/十字弓]箭头名称; [equipped:枪]子弹名称
一键搞定任何远程武器的使用。弓/十字弓/枪把我忘了中文版是不是这么写，按K查看一下就可
3。顺劈
/script SetCVar("targetNearestDistance",5)
/targetenemy
/cast 顺劈斩
/startattack
/script SetCVar("targetNearestDistance",41) 第1行和第5行是设定最小自动选择目标的距离。
原始的顺劈是这样的：
如果你当前没有选中目标，按下顺劈技能，系统会自动选择前方最近的一个目标，不管是否在近战距离内。
如果你当前选中了目标，那么不管怎么按都不会改变目标，就算目标在很远的地方而你鼻子底下就有另一个目标也好。
那么战场里有时会遇到这样的情况：你怒气足够，目标A和B都在5码内。你选中A并按下顺劈，但在下一次攻击出手前A跑出了近战距离，而B仍在近战范围内。这时你得手动切至B----这个宏就是替你做了这事：永远选择离自己5码内的任意目标来顺劈。
这听起来有点多余，但实战中经常就是那么手动切换的一点延迟让A逃出了B的近战范围。如果人再多点，场面再混乱点，B是个侏儒然后还有贼不时晕你等等等等更是如此。
4。双黄
/cast 毁灭打击
/stopcasting
/cast 英勇打击
防战的泄怒宏。而在刚开始5破前也能利用公共cd来跳过毁灭，当纯粹的英勇用
与此结构类似的有：
#show 复仇
/cast 复仇
/stopcasting
/cast 盾牌格挡
5。坐骑/斩杀
/cast [combat] 斩杀
/use [modifier:shift,nocombat,outdoors,flyable] 飞行坐骑物品名称1; [nocombat,outdoors,flyable] 飞行坐骑物品名称2
/use [nocombat,outdoors,noflyable] 地面坐骑物品名称
/dismount [mounted]
如果人物在战斗状态，那么这个按钮是斩杀---包括图标在内。
如果人物在非战斗状态且在外域，那么用飞行坐骑；按住shift点击则是用另一种飞行坐骑，适合平时骑鱼片采集，在集合石前则骑龙显摆的人
如果在老世界，则用千金马。----所有图标自动变成相应坐骑的。
这个看起来比较古怪的宏事实上是我最满意的宏之一，tbc键位严重短缺，坐骑这东西给快捷键有点可惜，不给的话又不怎么方便，何况2种.....所以跟斩杀这种使用条件区分得非常明显的东西结合起来，用到现在无任何瑕疵
6。法术反射e799bee5baa6e58685e5aeb9330
/cast [equipped:盾牌] 法术反射
/equip [stance:1/2] 单手武器名称
/equip [stance:1/2,noequipped:盾牌] 盾牌名称
如果装备了盾就用反射，否则先装上剑盾再用反射，多按一次
7。切换姿态+换武器
防御：
#show 防御姿态
/equip [stance:2,noequipped:单手剑] 单手武器名称
/equip [stance:2,noequipped:盾牌] 盾牌名称
/cast 防御姿态
去掉方括号和其中的内容可实现按一次就切换姿态+武器，否则按两次
第二行的"单手剑"可以是其他单手武器类型，对应你不常见的、特殊场合下使用的tank武器的类型。
比如说，一般不拿风剑去顶双子，要换上个.......混乱吧。那么第二行就是：
/equip [stance:2,noequipped:单手斧] 风剑名称
如果你拿的是非单手斧武器，那么这会使你换上风剑；如果你拿的是单手斧(准备顶双子了)，那么就不会给你换风剑。如果你已经持着风剑，这行也不会做任何事。
(拿混乱举例是为了说明类型，那么慢的东西不适合tank)
第一行的#show是为了保证这个宏看上去和防御姿态的图标一模一样.......不加这一行，防御姿态下这个图标周围一圈并不会变亮
狂暴：
#show 狂暴姿态
/equip [stance:3,noequipped:双手斧] 武器名称
/cast 狂暴姿态
同上
战斗：
#show 战斗姿态
/equip [stance:1] 武器名称
/cast [stance:1] 压制; 战斗姿态
第二行去掉方括号内的限制只是为了说明这也可以，当然也能按前两个那样加上
第三行里顺路加入压制，不加也没所谓。如果不能放压制，姿态还是照切。
换双持武器：
/equipslot 16 主手武器名称
/equipslot 17 副手武器名称
双手武器和剑盾互换，不包括切姿态：
/equip [noequipped:单手剑] 单手武器名称
/equip [noequipped:盾牌] 盾牌名称
/equip [noequipped:双手斧] 双手武器名称
第一行的剑和第三行的斧按具体情况替换成自己用的武器类型
8。破胆+停止攻击
#showtooltip 破胆怒吼
/cast 破胆怒吼
/stopattack
第一行可不要，只是给这宏加上鼠标移上去后的破胆技能提示。也可加入绷带的使用，在以上三行后面接上这两句：
/stopcasting
/use [target=player] (绷带名)
但这么绑不太灵活，确保你破胆时不处于公共cd中，否则可能浪费绷带机会
9。援护
#showtooltip 援护
/cast [help] 援护; [target=targettarget, help] 援护
/startattack [target=harm]
如果目标是友善的那么援护；如果目标是敌对，那么对其目标援护
总之就是不用切目标就能第一时间援护
10。farm宏
#showtooltip [stance:1/2]雷霆一击; [stance:3]乘胜追击
/cast [modifier:alt]乘胜追击; [stance:1] 雷霆一击
/stopcasting
/cast [nomodifier, stance:1] 狂暴姿态
/cast [stance:3] 乘胜追击
这就是不太有普遍性的宏了，因为这个追击显然也能在战斗姿态下用
然而2个触发公共cd的技能是不能连着写的，因此要靠姿态绕过这限制.......
这个也可以改造成小副本用的tank开怪宏，很省心：
#showtooltip [stance:1]挫志怒吼; [stance:2]雷霆一击
/cast [stance:1] 挫志怒吼
/stopcasting
/cast [stance:1] 防御姿态
/cast [stance:2] 雷霆一击
11。压制宏
压制现在有两种实现方式。
第一是和姿态切换整合：
#show 战斗姿态
/cast [stance:1] 压制; 战斗姿态
用这个宏来切换战斗姿态，切过来后能压就压，不能也没副作用，猛按就行。省一个格子
第二是
#show 压制
/castsequence reset=4 压制, 狂暴姿态
放了压制后再点直接切回狂暴。如果压制不亮那么不会切，如果压制打出去但被格挡招架未命中了，仍然会切狂暴。
如果你在第二技能栏，也就是不随姿态而变化的那些栏上有空余位置也可以这么写：
#show 压制
/castsequence reset=4 战斗姿态, 压制, 狂暴姿态
压制亮不亮都会切战斗，然而如果不能用的话就切不回狂暴了。